В процессе изучения книги «Бережливое производство плюс Шесть сигм в сфере услуг» наткнулся на график стратегической позиции брендов:

График стратегической позиции брендов

Такой график покажет, насколько конкурентоспособны предложения вашей компании, используя данные о «голосе клиента» и статистику рынка и бренда.

Ось Y графика показывает, обеспечивает ли данная отрасль в целом получение экономической прибыли для каждого продукта/услуги в среднем.

Размер кругов соответствует выручке для каждого бренда.

Местоположение кругов на графике определяется сочетанием конкурентоспособности и рыночной рентабельности.

Например, Бренд А занимает оптимальную позицию: он обеспечивает высокий валовый доход (размер круга большой), расположен на рентабельном рынке и имеет высокую конкурентоспособность.

Смена подхода

Такой график стратегической позиции можно легко приспособить к компании сферы услуг (например, банковских), где в качестве брендов могут выступать продукты или услуги.

В таком случае по оси Y у нас остается оценка рыночной рентабельности (на будущем графике будет принимать значения от -1 до +1), по оси X – конкурентоспособность (определяется по «голосу клиента» и может принимать значения от 0 до 10), размер кругов определяет доходность продукта.

Построение графика

Excel располагает графиком «пузырькового» типа, который мы можем использовать и в данном случае.

Введем пробные данные в таблицу:

Диаграмма стратегической позиции - Ввод данных

Подготовим таблицу для дальнейшего использования:

  • Ячейке A1 присвоим имя “tbl” для определения начала таблицы в макросе (см. ниже)
  • В диспетчере имен добавим имя “rowcnt” со следующей формулой (она позволит автоматически подсчитывать количество строк в таблице, ориентируясь на столбец A):

=СЧЁТЗ(Лист1!$A:$A)-1

Создадим пузырьковый график, но не будем пока заполнять его данными. Мы создадим макрос, который будет делать это автоматически. Решение использовать макрос продиктовано также тем, что пузырьковый график не дает возможности быстро добавлять или удалять данные.

В редакторе Visual Basic (Alt + F11) в объекте с листом, на котором расположен график (в нашем случае Лист1), создадим процедуру.

Диаграмма стратегической позиции - Visual Basic

Комментарии в макросе помогут разобраться с его содержимым.

Sub StrategyBubble()
    
    ' Очистим график - удалим из него все данные
    Dim fsc As Series
    Worksheets(1).ChartObjects(1).Activate
    For Each fsc In ActiveChart.FullSeriesCollection
        fsc.Delete
    Next
    
    Dim i As Integer        ' Переменная для перехода по строкам (продуктам)
    Dim counter As Integer  '            для подсчета количества рядов графика
    counter = 1             ' Начинаем подсчет с единицы
    
    For i = 1 To [rowcnt]
        ActiveChart.SeriesCollection.NewSeries ' Добавляем новый ряд в график
        With ActiveChart.FullSeriesCollection(counter)
            .HasLeaderLines = False
            .Name = ActiveSheet.Cells([tbl].Row + i, [tbl].Column).Value ' Присваиваем ряду значение, соответсвующее ячейке в столбце A таблицы
            .XValues = ActiveSheet.Cells([tbl].Row + i, [tbl].Column + 2).Value ' Устанавливаем значение по оси X
            .Values = ActiveSheet.Cells([tbl].Row + i, [tbl].Column + 1).Value ' Устанавливаем значение по оси Y
            .BubbleSizes = ActiveSheet.Cells([tbl].Row + i, [tbl].Column + 3).Value ' Устанавливаем размер круга
            .DataLabels.ShowSeriesName = True ' Добавляем подписи данных: имя ряда
            .DataLabels.ShowValue = False     '                           значение по оси Y не показываем
            .DataLabels.ShowBubbleSize = True '                           размер круга
            .DataLabels.Separator = "" & Chr(13) & "" ' В качестве разделителя в подписи данных используем перенос строки
            counter = counter + 1
        End With
    Next i
    
End Sub

Если будут вопросы – пишите в комментариях!

Готовую версию графика вы можете скачать здесь

Добавить комментарий


Защитный код
Обновить

Вверх